Textbestandteile von Spaltennamen mittels Power Query umbenennen

Aus Spaltenzeichnungen in Tabellen wiederkehrende Textbestandteile zu entfernen oder zu ersetzen, kann mit Hilfe von Power Query sehr einfach sein. In diesem Beitrag möchte ich Dir eine selbst erstellte Funktion vorstellen, die Dir das Leben erleichtern wird

Als Abonnent meines Newsletters erhältst Du die Beispieldateien zu den Beiträgen dazu. Hier geht’s zum Abonnement des Newsletters!

DIE PROBLEMSTELLUNG

In einem aktuellen Projekt erhielt ich verschiedene Tabellen als Datenquelle, in welchen alle Spalten mit bestimmten Präfixen versehen waren. In jeder Tabelle war es der Name der Datenquelle, der in jeder Spalte als Präfix vorhanden war. Du kannst es Dir so vorstellen, wie in folgender Abbildung:

Um mir die Arbeit einfacher zu machen, habe ich eine benutzerdefinierte Funktion fnReplaceColumnNameParts() geschrieben, die Du Dir im folgenden Abschnitt herunterladen kannst.

fnReplaceColumnNameParts()

	let
	fn=( Tabelle as table, ZuErsetzenderText as text, optional TextErsetzenDurch as text ) as table =>
	let
	/*
	//Parameter fürs Debuggen oder Erweitern der Funktion
	Tabelle = Tabelle,
	ZuErsetzenderText = "MeinDWH.",
	TextErsetzenDurch = "abc",
	*/
	//Aufbau der Liste, die die Spaltenpaarungen mit alten und neuem SPaltennamen beinhaltet
	SpaltenUmbenennung = List.Transform( Table.ColumnNames(Tabelle), each {_, Text.Replace(_,ZuErsetzenderText, if TextErsetzenDurch = null then "" else TextErsetzenDurch)} ),
	//Tatsächliche Umbenennung der Spalten
	Output = Table.RenameColumns(Tabelle,SpaltenUmbenennung)
	in
	Output,
	fnType = type function(
	Tabelle as table,
	ZuErsetzenderText as text,
	optional TextErsetzenDurch as text
	) as table meta [
	Documentation.Name="fnReplaceColumnNameParts (von Lars Schreiber --> ssbi-blog.de)",
	Documentation.LongDescription="Diese Funktion ersetzt wiederkehrende Teile von SPaltenüberschriften durch eine gewünschte Zeichenkette (die optional leer sein kann)",
	Documentation.Author="Lars Schreiber, ssbi-blog.de"
	]
	in
	Value.ReplaceType(fn, fnType)

view raw fnReplaceColumnNameParts.pq hosted with by GitHub

Falls Du wissen möchtest, wie Du eine Funktion in Power BI wiederverwendest, findest Du hier eine kurze Anleitung dazu. Als nächstes möchte ich ein paar Worte zu den Parametern dieser Funktion verlieren.

Die Funktion verfügt über 3 Parameter, 2 notwendige und einen optionalen.

• Notwendiger Parameter Tabelle: Dies ist die Tabelle, deren Überschriften verändert werden sollen.
• Notwendiger Parameter ZuErsetzenderText: Dies ist der Teil der jeweiligen Spaltenüberschrift, der ersetzt werden soll. In meinem Screenshot wäre dies „MeinDWH.„
• Optionaler Parameter TextErsetzenDurch: Wird dieser Parameter nicht angegeben, so wird der Parameter ZuErsetzenderText durch einen Leerwert ersetzt, andernfalls durch den Text, der mit dem Parameter TextErsetzenDurch übergeben wird.

Das folgende Video zeigt Dir die Nutzung der Funktion im Detail.

LÖSUNGSVIDEO

Danke für Dein Interesse und bis zum nächsten Mal. Denk dran: Sharing is caring. Wenn Dir der Beitrag gefallen hat, dann teile ihn gerne. Falls Du Anmerkungen hast, schreibe gerne einen Kommentar, oder schicke mir eine Mail an lars@ssbi-blog.de

Lars Schreiber

Lars ist Berater, Entwickler und Trainer für Microsoft Power BI. Er ist zertifizierter Power BI-Experte und Microsoft Trainer. Für sein Engagement in der internationalen Community wurde Lars seit 2017 jährlich durch Microsoft der MVP-Award verliehen. Lies hier mehr…